茶艺学校:在VBA代码中引用Excel工作表中单元格区域的方式小

来源:百度文库 编辑:九乡新闻网 时间:2024/03/29 21:51:07
问题一:在VBA代码中,如何引用当前工作表中的单个单元格(例如引用单元格C3)?
回答:可以使用下面列举的任一方式对当前工作表中的单元格(C3)进行引用。
(1) Range("C3")
(2) [C3]
(3) Cells(3, 3)
(4) Cells(3, "C")
(5) Range("C4").Offset(-1)
Range("D3").Offset(, -1)
Range("A1").Offset(2, 2)
(6) 若C3为当前单元格,则可使用:ActiveCell
(7) 若将C3单元格命名为“Range1”,则可使用:Range("Range1")或[Range1]
(8) Cells(4, 3).Offset(-1)

--------------------------------------------------------------------------------
问题二:在VBA代码中,我要引用当前工作表中的B2:D6单元格区域,有哪些方式?
回答:可以使用下面列举的任一方式对当前工作表中单元格区域B2:D6进行引用。
(1) Range(“B2:D6”)
(2) Range("B2", "D6")
(3) [B2:D6]
(4) Range(Range("B2"), Range("D6"))
(5) Range(Cells(2, 2), Cells(6, 4))
(6) 若将B2:D6区域命名为“MyRange”,则又可以使用下面的语句引用该区域:
① Range("MyRange")
② [MyRange]
(7) Range("B2").Resize(5, 3)
(8) Range("A1:C5").Offset(1, 1)
(9) 若单元格B2为当前单元格,则可使用语句:Range(ActiveCell, ActiveCell.Offset(4, 2))
(10) 若单元格D6为当前单元格,则可使用语句:Range("B2", ActiveCell)

--------------------------------------------------------------------------------
问题三:在VBA代码中,如何使用变量实现对当前工作表中不确定单元格区域的引用?
回答:有时,我们需要在代码中依次获取工作表中特定区域内的单元格,这通常可以采取下面的几种方式:
(1) Range(“A” & i)
(2) Range(“A” & i & “:C” & i)
(3) Cells(i,1)
(4) Cells(i,j)
其中,i、j为变量,在循环语句中指定i和j的范围后,依次获取相应单元格。

--------------------------------------------------------------------------------
问题四:在VBA代码中,如何扩展引用当前工作表中的单元格区域?
回答:可以使用Resize属性,例如:
(1) ActiveCell.Resize(4, 4),表示自当前单元格开始创建一个4行4列的区域。
(2) Range("B2").Resize(2, 2),表示创建B2:C3单元格区域。
(3) Range("B2").Resize(2),表示创建B2:B3单元格区域。
(4) Range("B2").Resize(, 2),表示创建B2:C2单元格区域。
如果是在一个单元格区域(如B3:E6),或一个命名区域中(如将单元格区域B3:E6命名为“MyRange”)使用Resize属性,则只是相对于单元格区域左上角单元格扩展区域,例如:
代码Range("C3:E6").Resize(, 2),表示单元格区域C3:D6,并且扩展的单元格区域可不在原单元格区域内。
因此,可以知道Resize属性是相对于当前活动单元格或某单元格区域中左上角单元格按指定的行数或列数扩展单元格区域。

--------------------------------------------------------------------------------
问题五:在VBA代码中,如何在当前工作表中基于当前单元格区域或指定单元格区域处理其它单元格区域?
回答:可以使用Offset属性,例如:
(1) Range("A1").Offset(2, 2),表示单元格C3。
(2) ActiveCell.Offset(, 1),表示当前单元格下一列的单元格。
(3) ActiveCell.Offset(1),表示当前单元格下一行的单元格。
(4) Range("C3:D5").Offset(, 1),表示单元格区域D3:E5,即将整个区域偏移一列。
从上面的代码示例可知,Offset属性从所指定的单元格开始按指定的行数和列数偏移,从而到达目的单元格,但偏移的行数和列数不包括指定单元格本身。

--------------------------------------------------------------------------------
问题六:在VBA代码中,如何在当前工作表中引用交叉区域?
回答:可以使用Intersect方法,例如:
Intersect(Range("C3:E6"), Range("D5:F8")),表示单元格区域D5:E6,即单元格区域C3:E6与D5:F8相重迭的区域。

--------------------------------------------------------------------------------
问题七:在VBA代码中,如何在当前工作表中引用多个区域?
回答:
(1) 可以使用Union方法,例如:
Union(Range("C3:D4"), Range("E5:F6")),表示单元格区域C3:D4和E5:F6所组成的区域。
Union方法可以将多个非连续区域连接起来成为一个区域,从而可以实现对多个非连续区域一起进行操作。
(2) 也可以使用下面的代码:
Range("C3:D4, E5:F6")或[C3:D4, E5:F6]
注意:Range("C3:D4", "F5:G6"),表示单元格区域C3:G6,即将两个区域以第一个区域左上角单元格为起点,以第二个区域右下角单元格为终点连接成一个新区域。
同时,在引用区域后使用Rows属性和Columns属性时,注意下面代码的区别:
①Range("C3:D4", "F8:G10").Rows.Count,返回的值为8;
②Range("C3:D4,F8:G10").Rows.Count,返回的值为2,即只计算第一个单元格区域。

--------------------------------------------------------------------------------
问题八:在VBA代码中,如何引用当前工作表中活动单元格或指定单元格所在的区域(当前区域)?
回答:可以使用CurrentRegion属性,例如:
(1) ActiveCell.CurrentRegion,表示活动单元格所在的当前区域。
(2) Range("D5").CurrentRegion,表示单元格D5所在的当前区域。
当前区域是指周围由空行或空列所围成的区域。该属性的详细使用参见《CurrentRegion属性示例》一文。

--------------------------------------------------------------------------------
问题九:在VBA代码中,如何引用当前工作表中已使用的区域?
回答:可以使用UsedRange属性,例如:
(1) Activesheet.UsedRange,表示当前工作表中已使用的区域。
(2) Worksheets("sheet1").UsedRange,表示工作表sheet1中已使用的区域。
与CurrentRegion属性不同的是,该属性代表工作表中已使用的单元格区域,包括显示为空行,但已进行过格式的单元格区域。该属性的详细使用参见《解析UsedRange属性》一文。

--------------------------------------------------------------------------------
问题十:如何在单元格区域内指定特定的单元格?
回答:可以使用Item属性,例如:
(1) Range("A1:B10").Item(5,3)指定单元格C5,这个单元格处于以区域中左上角单元格A1(即区域中第1行第1列的单元格)为起点的第5行第3列。因为Item属性为默认属性,因此也可以简写为:Range("A1:B10")(5,3)。
如果将A1:B10区域命名为”MyRange”,那么Range("MyRange")(5,3)也指定单元格C5。
(2) Range("A1:B10")(12,13)指定单元格M12,即用这种方式引用单元格,该单元格不必一定要包含在区域内。
同时,也不需要索引数值是正值,例如:
① Range("D4:F6")(0,0)代表单元格C3;
② Range("D4:F6")(-1,-2)代表单元格A2。
而Range("D4:F6")(1,1)代表单元格D4。
(3) 也可以在单元格区域中循环,例如:
Range("D4:F6")(2,2)(3,4)代表单元格H7,即该单元格位于作为左上角单元格E5的第3行第4列(因为E5是开始于区域中左上角单元格D4起的第2行第2列)。
(4) 也能使用一个单个的索引数值进行引用。计数方式为从左向右,即在区域中的第一行开始从左向右计数,第一行结束后,然后从第二行开始从左到右接着计数,依次类推。(注:从区域中第一行第一个单元格开始计数,当第一行结束时,转入第二行最左边的单元格,这样按一行一行从左向右依次计数。以单元格区域中第1个单元格开始,按上述规则依次为第2个单元格、第3个单元格….等等),例如:
Range("A1:B2")(1) 代表单元格A1;
Range("A1:B2")(2) 代表单元格B1;
Range("A1:B2")(3) 代表单元格A2;
Range("A1:B2")(4) 代表单元格B2。
这种方法可在工作表中连续向下引用单元格(即不一定是在单元格区域内,但在遵循相同的规律),例如:
Range("A1:B2")(5)代表单元格A3;
Range("A1:B2")(14)代表单元格B7,等等。
也可以使用单个的负数索引值。
这种使用单个索引值的方法对遍历列是有用的,例如,Range("D4")(1)代表单元格D4,Range("D4")(2)代表单元格D5,Range ("D4")(11)代表单元格D14,等等。
同理,稍作调整后也可遍历行,例如:
Range("D4").Columns(2)代表单元格E4,Range("D4").Columns(5)指定单元格H4,等等。
(5)当与对象变量配合使用时,Item属性能提供简洁并有效的代码,例如:
Set rng = Worksheets(1).[a1]
定义了对象变量后,像单元格方法一样,Item属性允许使用两个索引数值引用工作表中的任一单元格,例如,rng(3,4)指定单元格D3。(By Chip Pearson)

--------------------------------------------------------------------------------
问题十一:在VBA代码中,如何引用当前工作表中的整行或整列?
回答:见下面的示例代码:
(1) Range("C:C").Select,表示选择C列。
      Range("C:E").Select,表示选择C列至E列。
(2) Range("1:1").Select,表示选择第一行。
      Range("1:3").Select,表示选择第1行至第3行。
(3) Range("C:C").EntireColumn,表示C列;
      Range("D1").EntireColumn,表示D列。
同样的方式,也可以选择整行,然后可以使用如AutoFit方法对整列或整行进行调整。

--------------------------------------------------------------------------------
问题十二:在VBA代码中,如何引用当前工作表中的所有单元格?
回答:可以使用下面的代码:
(1) Cells,表示当前工作表中的所有单元格。
(2) Range(Cells(1, 1), Cells(Cells.Rows.Count, Cells. Columns.Count)),其中Cells.Rows表示工作表所有行,Cells. Columns表示工作表所有列。

--------------------------------------------------------------------------------
问题十三:在VBA代码中,如何引用工作表中的特定单元格区域?
回答:在工作表中,您可能使用过“定位条件”对话框。可以通过选择菜单“编辑——定位”,单击“定位”对话框中的“定位条件”按钮显示该对话框。这个对话框可以允许用户选择特定的单元格。例如:
(1) Worksheets("sheet1").Cells.SpecialCells(xlCellTypeAllFormatConditions),表示工作表sheet1中由带有条件格式的单元格所组成的区域。
(2) ActiveCell.CurrentRegion.SpecialCells(xlCellTypeBlanks),表示当前工作表中活动单元格所在区域中所有空白单元格所组成的区域。
当然,还有很多常量和值的组合,可以让您实现特定单元格的查找并引用。参见《探讨在工作表中找到最后一行》一文。

--------------------------------------------------------------------------------
问题十四:在VBA代码中,如何引用其它工作表或其它工作簿中的单元格区域?
回答:要引用其它工作表或其它工作簿中的单元格区域,只需在单元格对象前加上相应的引用对象即可,例如:
(1) Worksheets(“Sheet3”).Range(“C3:D5”),表示引用工作表sheet3中的单元格区域C3:D5。
(2) Workbooks(“MyBook.xls”).Worksheets(“sheet1”).Range(“B2”),表示引用MyBook工作簿中工作表Sheet1上的单元格B2。

--------------------------------------------------------------------------------
问题十五:还有其它的一些情形吗?
回答:列举如下:
(1) Cells(15),表示单元格O1,即可在Cells属性中指定单元格数字来选择单元格,其计数顺序为自左至右、从上到下,又如Cells(257),表示单元格B1。
(2) Cells(, 256),表示单元格IV1,但是如果Cells(, 257),则会返回错误。

--------------------------------------------------------------------------------
结语
我们用VBA对Excel进行处理,一般是对其工作表中的数据进行处理,因此,引用单元格区域是ExcelVBA编程中最基本的操作之一,只有确定了所处理的单元格区域,才能使用相应的属性和方法进行下一步的操作。
上面列举了一些引用单元格区域的情形和方式,可以看出,引用单元格区域有很多方式,有一些可能不常用,可以根据工作表的所处的环境和个人编程习惯进行选择使用。
当然,在编写程序时,也可能会将上面的一些属性联合使用,以达到选取特定操作对象的目的,例如Offset属性、Resize属性、CurrentRegion属性、UsedRange属性等的组合。


找到最后一行的一些方法探讨
使用End属性
在ExcelVBA中,使用End(xlUp)查找最后一行是最常使用且最为简单的方法,它假设要有一列总包含有数据(数字、文本和公式等),并且在该列中最后输入数据的单元格的下一行不会包含数据,因此不必担心会覆盖掉已有数据。但该方法有两个缺点:
(1) 仅局限于查找指定列的最后一行。
(2) 如果该列中最后一行被隐藏,那么该隐藏行将被视作最后一行。因此,在最后一行被隐藏时,其数据可能会被覆盖。但该列中间的隐藏行不会影响查找的结果。
[示例代码01]
Sub EndxlUp_OneColLastRow()
     If Range("A" & Rows.Count).End(xlUp) = Empty Then GoTo Finish
     '获取最后一行
     MsgBox "最后一行是第" & Range("A" & Rows.Count).End(xlUp).Row & “行.”
     Exit Sub
Finish:
     MsgBox "没有发现公式或数据! "
End Sub
[示例代码02]
Sub NextRowInColumnUsedAsSub()
'包含所有数据和公式,忽略隐藏的最后一行
     Range("A" & Range("A" & Rows.Count).End(xlUp).Row + 1).Select
End Sub
[示例代码03]
Sub NextRowInColumnUsedAsFunction()
'包含所有数据和公式,忽略隐藏的最后一行
     Range("A" & LastRowInColumn("A") + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - - - - - -
Public Function LastRowInColumn(Column As String) As Long
        LastRowInColumn = Range(Column & Rows.Count).End(xlUp).Row
End Function
注意,要输入新数据的列可能与我们所查找最后一行时所使用的列不同,例如,在上例中,我们可以修改为在B列中查找该列的最后一行,而在A列相应行的下一行中输入新的数据。

--------------------------------------------------------------------------------
使用Find方法
Find方法在当前工作有数据中进行查找,不需要指定列,也可以确保不会意外地覆盖掉已有数据。其中,参数LookIn指定所查找的类型,有三个常量可供选择,即xlValues、xlFormulas和xlComments。
(1) 常量xlFormulas将包含零值的单元格作为有数据的单元格。(当设置零值不显示时,该单元格看起来为空,但该参数仍将该单元格视为有数据的单元格)
(2) 常量xlValues将包含零值的单元格(如果设置零值不显示时)作为空白单元格,此时,若该单元格在最后一行,则Find方法会认为该单元格所在的行为空行,因此,该单元格中的内容可能会被新数据所覆盖。
[注:在Excel中,选择菜单“工具”——“选项”,在打开的“选项”对话框中,选择“视图”选项卡,将其中的“零值”前的复选框取消选中,则工作表中的零值都不会显示]
如果在参数LookIn中使用常量xlValues的话,还存在一个问题是:如果您将最后一行隐藏,则Find方法会认为倒数第二行是最后一行,此时您在最后一行的下一行输入数据,则会将实际的最后一行的数据覆盖。
您可以在隐藏最后一行与不隐藏最后一行,或者是最后一行显示零值与不显示零值时,运行下面的示例代码04,看看所得的结果有什么不同。
[示例代码04]
Sub Find_LastRowxlValues()
      On Error GoTo Finish
      '获取最后一行
      MsgBox "最后一行是第" & Cells.Find("*", _
      SearchOrder:=xlByRows, LookIn:=xlValues, _
      SearchDirection:=xlPrevious).EntireRow.Row & “行”
      Exit Sub
Finish:
      MsgBox "没有发现数值!"
End Sub
因此,在使用Find方法时,您应该考虑所选参数设置的常量,以及工作表最后一行是否有可能被隐藏或不显示零值。如果您忽视这些情况,很可能得不到您想要的结果,或者是覆盖掉已有数据。使用常量xlFormulas可以避免这个问题,如下面的示例代码05所示。
[示例代码05]
Sub Find_LastRowxlFormulas()
      On Error GoTo Finish
      '获取最后一行
      MsgBox "最后一行是第" & Cells.Find("*", _
      SearchOrder:=xlByRows, LookIn:=xlFormulas, _
      SearchDirection:=xlPrevious).EntireRow.Row & “行”
      Exit Sub
Finish:
      MsgBox "没发现数值或公式!"
End Sub
下面再列举几个示例代码。
[示例代码06]
Sub NextRowUsedAsSub()
'选取最后一行的下一行
     Range("A" & Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row + 1).Select
End Sub
[示例代码07]
Sub NextRowUsedAsFunction()
'选取最后一行的下一行(调用函数)
     Range("A" & LastRow + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - - - - - -
Public Function LastRow() As Long
'本代码包含隐藏行
'使用常量xlFormulas,因为常量xlValues会忽略隐藏的最后一行
     LastRow = Cells.Find("*", LookIn:=xlFormulas, SearchDirection:=xlPrevious).Row
End Function
注:Find方法中,参数LookIn的默认值为xlFormulas。

--------------------------------------------------------------------------------
使用SpecialCells方法
SpecialCells方法用于查找指定类型的值,其语法为SpecialCells(Type,Value),有两种主要的使用方式:
(1) 若参数Type仅考虑常量,则在查找时会忽略和覆盖由公式生成的任何数据,如示例代码08所示。
(2) 若参数Type仅考虑由公式生成的数据,则在查找时会忽略和覆盖任何常量数据,如示例代码09所示。
如果参数Type是xlCellTypeConstants或者是xlCellTypeFormulas,则Value参数可使用常量决定哪种类型的单元格将被包含在结果中,这些常量值能组合而返回多个类型,其缺省设置是选择所有的常量或公式,而不管是何类型,可使用下面四个可选的常量:
1) xlTextValues(包含文本);        2) xlNumbers(包含数字);
3) xlErrors(包含错误值);          4) xlLogical(包含逻辑值)
自已在工作表输入一些含有数值和公式的数据,隐藏或不隐藏最后一行或公式所在的行,先体验下面的两段示例代码。
[示例代码08]
'当最后一行为公式或隐藏了最后行时,会忽略,即认为倒数第二行为最后一行
Sub NextConstantRowFunction()
        Range("A" & LastConstantRow(True, True, True, True) + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - - - - - - -
Public Function LastConstantRow(Optional IncludeText As Boolean, _
                                  Optional IncludeNumbers As Boolean, _
                                  Optional IncludeErrors As Boolean, _
                                  Optional IncludeLogicals As Boolean) As Long
      Dim Text As Long, Numbers As Long, Errors As Long
      Dim Logical As Long, AllTypes As Long
      If IncludeText Then Text = xlTextValues Else Text = 0
      If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
      If IncludeErrors Then Errors = xlErrors Else Errors = 0
      If IncludeLogicals Then Logical = xlLogical Else Logical = 0
      AllTypes = Text + Numbers + Errors + Logical
      On Error GoTo Finish
      LastConstantRow = Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$") _
          (UBound(Split(Cells.SpecialCells(xlCellTypeConstants, AllTypes).Address, "$")))
        Exit Function
Finish:
        MsgBox "没有发现数据!"
End Function
[示例代码09]
'查找含有公式的单元格所在的行,忽略该行以后的常量和隐藏的行
Sub NextFormulaRowFunction()
        Range("A" & LastFormulaRow(True, True, True, True) + 1).Select
End Sub
'- - - - - - - - - - - - - - - - - - -
Public Function LastFormulaRow(Optional IncludeText As Boolean, _
                                  Optional IncludeNumbers As Boolean, _
                                  Optional IncludeErrors As Boolean, _
                                  Optional IncludeLogicals As Boolean) As Long
     Dim Text As Long, Numbers As Long, Errors As Long
     Dim Logical As Long, AllTypes As Long
     If IncludeText Then Text = xlTextValues Else Text = 0
     If IncludeNumbers Then Numbers = xlNumbers Else Numbers = 0
     If IncludeErrors Then Errors = xlErrors Else Errors = 0
     If IncludeLogicals Then Logical = xlLogical Else Logical = 0
     AllTypes = Text + Numbers + Errors + Logical
     On Error GoTo Finish
     LastFormulaRow = Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$") _
         (UBound(Split(Cells.SpecialCells(xlCellTypeFormulas, AllTypes).Address, "$")))
     Exit Function
Finish:
     MsgBox "没有发现数据!"
End Function
下面的示例代码10忽略最后一行带有公式的单元格,即当最后一行的单元格中含有公式时,将倒数第二行作为最后一行,即只考虑直接输入到工作表中的数据。当最后一行没有公式但被隐藏时,并不影响该方法的判断。
[示例代码10]
Sub SpecialCells_LastRowxlCellTypeConstants()
      Dim MyRow As Range
      On Error GoTo Finish
      Set MyRow = Intersect([A:A], Cells. _
      SpecialCells(xlCellTypeConstants).EntireRow).EntireRow
     '获取最后一行
      MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
      (UBound(Split(MyRow.Address, "$"))) & “行”
      Set MyRow = Nothing
      Exit Sub
Finish:
      MsgBox "没有发现数据!"
End Sub
注:因为上述代码使用了’Split’函数,故只适合于Office2000及以上的版本。
该方法也允许我们指定单个数据类型,诸如数字数据或文本数据,如下所示。
下面,我们查找的最后一行是仅在行中有数字(而不包含公式)的单元格的最后一行。
[示例代码11]
Sub SpecialCells_LastRowxlCellTypeNumberConstants()
      Dim MyRow As Range
      On Error GoTo Finish
      Set MyRow = Intersect([A:A], Cells. _
      SpecialCells(xlCellTypeConstants, xlNumbers).EntireRow)
      '获取最后一行
      MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
      (UBound(Split(MyRow.Address, "$"))) & “行”
      Set MyRow = Nothing
      Exit Sub
Finish:
      MsgBox "没有发现数据!"
End Sub
下面,我们查找的最后一行是仅在行中有文本(而不包含公式)的单元格的最后一行。
[示例代码12]
Sub SpecialCells_LastRowxlCellTypeTextConstants()
      Dim MyRow As Range
      On Error GoTo Finish
      Set MyRow = Intersect([A:A], Cells. _
      SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow)
     '获取最后一行
      MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
      (UBound(Split(MyRow.Address, "$"))) & “行”
      Set MyRow = Nothing
      Exit Sub
Finish:
      MsgBox "没有发现数据!"
End Sub
下面,我们查找的最后一行是仅在行中有公式的单元格的最后一行。
[示例代码13]
Sub SpecialCells_LastRowxlCellTypeFormulas()
      Dim MyRow As Range
      On Error GoTo Finish
      Set MyRow = Intersect([A:A], Cells. _
      SpecialCells(xlCellTypeFormulas).EntireRow).EntireRow
     '获取最后一行
      MsgBox "最后一行是第" & Split(MyRow.Address, "$") _
      (UBound(Split(MyRow.Address, "$"))) & “行”
      Set MyRow = Nothing
      Exit Sub
Finish:
      MsgBox "没有发现数据!"
End Sub
同上面所讲述的一样,我们也能使用SpecailCells方法去找到其它特定类型的单元格所在的最后一行,下面是这些常量的一个完整的列表:
XlCellTypeAllFormatConditions (任何格式的单元格)
XlCellTypeAllValidation (带有数据有效性的单元格)
XlCellTypeBlanks (所使用区域中的空白单元格)
XlCellTypeComments (包含有批注的单元格)
XlCellTypeConstants (包含有常量的单元格)
XlCellTypeFormulas (包含有公式的单元格)
XlCellTypeLastCell (已使用区域中的最后一个单元格(看下面))
XlCellTypeSameFormatConditions (有相同格式的单元格)
XlCellTypeSameValidation (有相同数据有效性条件的单元格)
XlCellTypeVisible (工作表中所有可见的单元格)